|
DB2 Example: Change Remote Journal State
CL Command Source
CMD PROMPT('Change Journal State')
PARM KWD(STATUS) TYPE(*CHAR) LEN(1) RSTD(*YES) +
VALUES(A I) MIN(1) PROMPT('Activate +
or Inactivate?')
PARM KWD(LCLRMT) TYPE(*CHAR) LEN(1) RSTD(*YES) +
VALUES(L R) MIN(1) PROMPT('Local Or +
Remote?')
PARM KWD(JRNNAME) TYPE(QJRNNAME) MIN(1) +
PROMPT('Journal Name')
PARM KWD(RDBDIRE) TYPE(*CHAR) LEN(18) MIN(0) +
PMTCTL(REMOTE) PROMPT('Remote RDB +
Directory Entry')
PARM KWD(RJRNNAME) TYPE(QRJRNNAME) PMTCTL(REMOTE) +
PROMPT('Remote Journal Name')
PARM KWD(STRJRNRCV) TYPE(QSTRJRNRCV) +
DFT(*ATTACHED) SNGVAL((*ATTACHED) +
(*SRCSYS)) PMTCTL(RMTACT) +
PROMPT('Starting Journal Receiver Name')
PARM KWD(PRFINACTYP) TYPE(*CHAR) LEN(1) +
RSTD(*YES) DFT(C) VALUES(C I) +
PMTCTL(RMTINACT) PROMPT('Preferred +
Inactive Type')
PARM KWD(SYNASY) TYPE(*CHAR) LEN(1) RSTD(*YES) +
DFT(A) VALUES(S A) PMTCTL(RMTACT) +
PROMPT('Synch or Async Maintained?')
PARM KWD(SNDTSKPRI) TYPE(*INT4) DFT(0) +
PMTCTL(ASYNC) PROMPT('Sending Task Priority')
QJRNNAME: QUAL TYPE(*NAME) LEN(10) MIN(1)
QUAL TYPE(*NAME) LEN(10) SPCVAL((*LIBL) +
(*CURLIB)) MIN(1) PROMPT('Library')
QRJRNNAME: QUAL TYPE(*NAME) LEN(10) DFT(*JRN) SPCVAL((*JRN)) +
MIN(0)
QUAL TYPE(*NAME) LEN(10) PROMPT('Library')
QSTRJRNRCV: QUAL TYPE(*NAME) LEN(10) MIN(1)
QUAL TYPE(*NAME) LEN(10) SPCVAL((*LIBL) +
(*CURLIB)) PROMPT('Library')
REMOTE: PMTCTL CTL(LCLRMT) COND((*EQ R))
RMTACT: PMTCTL CTL(LCLRMT) COND((*EQ R))
PMTCTL CTL(STATUS) COND((*EQ A))
RMTINACT: PMTCTL CTL(LCLRMT) COND((*EQ R))
PMTCTL CTL(STATUS) COND((*EQ I))
ASYNC: PMTCTL CTL(SYNASY) COND((*EQ A))
PMTCTL CTL(STATUS) COND((*EQ A))
PMTCTL CTL(LCLRMT) COND((*EQ R))
| 
